FUNCTION Fitscard, name, value, comment
;+
; NAME:
;       FITSCARD
; PURPOSE:
;       Generate a FITS header entry
; CATEGORY:
;       
; CALLING SEQUENCE:
;       RESULT = FITSCARD ( NAME , VALUE [, COMMENT] )
; INPUTS:
;       NAME  : (string) name for the entry. Will be inserted in capital
;               letters.
;       VALUE : value for NAME. Converted to string.
; OPTIONAL INPUT PARAMETER:
;       COMMENT : Comment for the entry. separated from the value field
;                 by a '/' in coloumn 31
; OUTPUTS:
;       RESULT : 80-character-string of the form
;                NAME    =  <VALUE>    \ <Comment>
; MODIFICATION HISTORY:
;       10-Okt-1992  P.Suetterlin, KIS
;-

on_error, 2
IF n_params() LT 2 THEN $
  message, 'USAGE:  RESULT = FITSCARD ( NAME , VALUE , [Comment] )'
card = string(replicate(32b, 80))
strput, card, strupcase(name), 0
strput, card, '=', 8
IF n_params() GT 2 THEN BEGIN
    vlen = strlen(string(value))
    strput, card, string(value), 30-vlen
    strput, card, '/', 31
    strput, card, comment, 32
ENDIF ELSE strput, card, value, 10
return, card

END