PRO inorm,date,x1,x2,y1,y2,ncarr
;
;Normalization and rms granular contrast calculation of IR images.
;INPUT:  date = 23 or 25
;	 x1,x2,y1,y2 = boundaries of granular subfield
;	 files XXjun/ifXX.seq, where XX is the date
;OUTPUT: ncarr = 2-column array with mean and rms contrast
;	 files XXjun/inXX.seq  -  normalized frames
;
on_error,1

if (date ne 23) and (date ne 25) then  $
   message,'Sorry, I do not know how to handle this dataset'
dat=strtrim(date,2)
nami=dat+'jun/if'+dat+'.'
namo=dat+'jun/in'+dat+'.'
if date eq 23 then n=320 else n=359
im=intarr(224,224)
ncarr=fltarr(2,n+1)

for i=0,n do begin
  openr,1,nami+strtrim(i,2)
  readu,1,im
  close,1
  ima=reverse(im,1)		;to get orientation as in WL
  ig=ima(x1:x2,y1:y2)		;granular field
  std=stdev(ig,mea)
  ig=ig<mea+3*std	;limitation to +/- 3 sigma to avoid
  ig=ig>mea-3*std	;  the influence of bad pixels
  std=stdev(ig,mea)	;final statistics
  ncarr(0,i)=mea
  ncarr(1,i)=std/mea
  ima=ima/mea*10000.
  ima=nint(ima)
  print,namo+strtrim(i,2)
  openw,1,namo+strtrim(i,2)
  writeu,1,ima
  close,1
endfor

END