PRO readradlos_id,init_model,id,radtab,flag
; 
; Reading radiative losses from the database
; 
; INPUT:
;  init_model (string) in the form 'C' defines the folder name
;  id (integer) - ID number of the model in the folder 'Radiative_Losses/VAL_'+init_model
; OUTPUTS:
;  radtab - radiative-losses array DOUBLE(6,103)
;     [h,m,LH,LCa,LMg,Ltot] - height [km], col.mass [g/cm^2], losses for H, CaII, MgII,
;                             and total losses [erg/s/cm^3]
;  flag = 1 when the output is ok, flag = 0 when the output contains NaN
;

id=id<2988>0
tp=-0.03+(id/49)*0.001
mp=0.2+(id mod 49)*0.1
print,'Model T-par, m-par, ID:  ',tp,mp,id

model_name='Radiative_Losses/VAL_'+init_model+'/RADLOS'+string(id,format='(I05)')+'.DAT'
radtab=dblarr(6,103)
flag=1

openr,1,model_name
for j=0,102 do begin
  readf,1,dum,z,m,LH,LCa,LMg,format='(I3,2F10.7,3F12.9)'
  radtab[0,j]=z
  radtab[1,j]=m
  radtab[2,j]=LH
  radtab[3,j]=LCa
  radtab[4,j]=LMg
  radtab[5,j]=LH+LCa+LMg
endfor
close,1

; Geometric height
radtab[0,*]=(radtab[0,102]-7.5e6-radtab[0,*])/1.e5

; Presence of NaNs
if total(finite(radtab)) ne n_elements(radtab) then flag=0

; Plot
if flag eq 1 then begin
  loadct,2
  plot,radtab[0,*],radtab[5,*],xra=[500,2500],col=0,back=255, $
    title='Model '+init_model+'-'+string(id,format='(I04)'), $
    xtit='h [km]',ytit='L [erg s!U-1!N cm!U-3!N]',charsiz=1.5
  oplot,radtab[0,*],radtab[2,*],col=80    ; hydrogen (red)
  oplot,radtab[0,*],radtab[3,*],col=180   ; Ca II (violet)
  oplot,radtab[0,*],radtab[4,*],col=20    ; Mg II (green)
; write_png,'C:\Users\Michal\DATA\data\IRIS\calibration\CF_RL-examples\'+init_model+'-'+string(id,format='(I04)')+'RL.png',tvrd(/true)
  loadct,3
endif

END